[arch-commits] Commit in check-sieve/repos (2 files)
George Rawlinson
grawlinson at gemini.archlinux.org
Wed May 25 07:57:30 UTC 2022
Date: Wednesday, May 25, 2022 @ 07:57:30
Author: grawlinson
Revision: 1210328
archrelease: copy trunk to community-x86_64
Added:
check-sieve/repos/community-x86_64/
check-sieve/repos/community-x86_64/PKGBUILD
(from rev 1210327, check-sieve/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: check-sieve/repos/community-x86_64/PKGBUILD (from rev 1210327, check-sieve/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD (rev 0)
+++ community-x86_64/PKGBUILD 2022-05-25 07:57:30 UTC (rev 1210328)
@@ -0,0 +1,59 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Geoffrey Frogeye <geoffrey+aur at frogeye.fr>
+
+pkgname=check-sieve
+pkgver=0.8
+pkgrel=1
+pkgdesc='Syntax checker for Sieve scripts'
+arch=('x86_64')
+url='https://github.com/dburkart/check-sieve'
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('git')
+checkdepends=('python')
+_commit='18bb1f9ac8b233ac29f94212f94148b7855af714'
+source=("$pkgname::git+$url#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+ cd "$pkgname"
+
+ git describe --tags | sed 's/^check-sieve-//'
+}
+
+prepare() {
+ cd "$pkgname"
+
+ # ensure LDFLAGS are passed to compiler
+ sed \
+ -i Makefile \
+ -e '/\t$(CXX).*/s/$/ $(LDFLAGS)/'
+}
+
+
+build() {
+ cd "$pkgname"
+
+ export CFLAGS+=" -ffat-lto-objects"
+
+ make
+}
+
+check() {
+ cd "$pkgname"
+
+ make test
+}
+
+package() {
+ cd "$pkgname"
+
+ make INSTALL_PREFIX="$pkgdir/usr" install
+
+ # license
+ install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+ # fix incorrect permissions on library
+ chmod 644 "$pkgdir/usr/lib/libchecksieve.a"
+}
+
More information about the arch-commits
mailing list