[arch-commits] Commit in ntfs-3g/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Antonio Rojas
arojas at gemini.archlinux.org
Thu May 26 21:19:40 UTC 2022
Date: Thursday, May 26, 2022 @ 21:19:39
Author: arojas
Revision: 446558
archrelease: copy trunk to testing-x86_64
Added:
ntfs-3g/repos/testing-x86_64/
ntfs-3g/repos/testing-x86_64/PKGBUILD
(from rev 446557, ntfs-3g/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: ntfs-3g/repos/testing-x86_64/PKGBUILD (from rev 446557, ntfs-3g/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-05-26 21:19:39 UTC (rev 446558)
@@ -0,0 +1,49 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Thomas Bächler <thomas.archlinux.org>
+
+pkgname=ntfs-3g
+_pkgname=ntfs-3g_ntfsprogs
+pkgver=2022.5.17
+pkgrel=1
+pkgdesc='NTFS filesystem driver and utilities'
+url='https://www.tuxera.com/community/open-source-ntfs-3g/'
+arch=('x86_64')
+license=('GPL2')
+depends=('util-linux' 'fuse2')
+source=("https://tuxera.com/opensource/${_pkgname}-${pkgver}.tgz")
+sha256sums=('0489fbb6972581e1b417ab578d543f6ae522e7fa648c3c9b49c789510fd5eb93')
+
+conflicts=('ntfsprogs')
+provides=('ntfsprogs')
+replaces=('ntfsprogs')
+
+prepare() {
+ cd ${_pkgname}-${pkgver}
+ sed 's|$(DESTDIR)/sbin|$(DESTDIR)/usr/bin|' -i {ntfsprogs,src}/Makefile.in
+}
+
+build() {
+ cd ${_pkgname}-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --sbin=/usr/bin \
+ --mandir=/usr/share/man \
+ --disable-ldconfig \
+ --disable-static \
+ --with-fuse=external \
+ --enable-xattr-mappings \
+ --enable-posix-acls \
+ --enable-extras \
+ --enable-crypto \
+
+ make
+}
+
+package_ntfs-3g() {
+ cd ${_pkgname}-${pkgver}
+ make DESTDIR="${pkgdir}" rootbindir=/usr/bin rootsbindir=/usr/bin rootlibdir=/usr/lib install
+ rm "${pkgdir}"/usr/share/man/man8/ntfsfallocate.8 # uninstalled binary
+ ln -s /usr/bin/ntfs-3g "${pkgdir}/usr/bin/mount.ntfs"
+}
More information about the arch-commits
mailing list