[arch-commits] Commit in lib32-libpulse/repos (2 files)

[Jan Steffens]

    Date: Saturday, May 28, 2022 @ 17:02:26
  Author: heftig
Revision: 1212417

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libpulse/repos/multilib-testing-x86_64/
  lib32-libpulse/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1212415, lib32-libpulse/trunk/PKGBUILD)

----------+
 PKGBUILD |   79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

Copied: lib32-libpulse/repos/multilib-testing-x86_64/PKGBUILD (from rev 1212415, lib32-libpulse/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2022-05-28 17:02:26 UTC (rev 1212417)
@@ -0,0 +1,79 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=16.0
+pkgrel=1
+arch=(x86_64)
+url="https://www.freedesktop.org/wiki/Software/PulseAudio/"
+license=(LGPL)
+depends=(lib32-{dbus,libasyncns,libcap,libxtst,libsm,libsndfile,systemd}
+         $_pkgbasename)
+makedepends=(lib32-{speexdsp,glib2,gtk3} git meson valgrind)
+optdepends=('lib32-alsa-plugins: ALSA support'
+            'lib32-glib2: mainloop integration')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(debug)
+_commit=237c5a5c36d49a51b1b7831b091ea250367c9102  # tags/v16.0^0
+source=("git+https://gitlab.freedesktop.org/pulseaudio/pulseaudio.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pulseaudio
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd pulseaudio
+
+  # Freeze version before patching
+  ./git-version-gen doesnt-exist >.tarball-version
+}
+
+build() {
+  local meson_options=(
+    --libdir /usr/lib32
+    -D avahi=disabled
+    -D bashcompletiondir=no
+    -D bluez5-gstreamer=disabled
+    -D bluez5=disabled
+    -D daemon=false
+    -D doxygen=false
+    -D elogind=disabled
+    -D fftw=disabled
+    -D gstreamer=disabled
+    -D jack=disabled
+    -D lirc=disabled
+    -D man=false
+    -D orc=disabled
+    -D pulsedsp-location='/usr/\$LIB/pulseaudio'
+    -D soxr=disabled
+    -D stream-restore-clear-old-devices=true
+    -D tcpwrap=disabled
+    -D tests=false
+    -D udevrulesdir=/usr/lib/udev/rules.d
+    -D webrtc-aec=disabled
+    -D zshcompletiondir=no
+  )
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  arch-meson pulseaudio build "${meson_options[@]}"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+  rm -r "$pkgdir/etc" "$pkgdir"/usr/{bin,include,share}
+}
+
+# vim:set sw=2 et: