[arch-commits] Commit in perl-shell-command/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sun May 29 11:52:27 UTC 2022
Date: Sunday, May 29, 2022 @ 11:52:26
Author: felixonmars
Revision: 1214478
archrelease: copy trunk to community-staging-any
Added:
perl-shell-command/repos/community-staging-any/
perl-shell-command/repos/community-staging-any/PKGBUILD
(from rev 1214475, perl-shell-command/trunk/PKGBUILD)
----------+
PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
1 file changed, 37 insertions(+)
Copied: perl-shell-command/repos/community-staging-any/PKGBUILD (from rev 1214475, perl-shell-command/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2022-05-29 11:52:26 UTC (rev 1214478)
@@ -0,0 +1,37 @@
+# Maintainer: Caleb Maclennan< caleb at alerque.com>
+# Contributor: Anton Leontiev <scileont at gmail.com>
+
+_cpan=Shell-Command
+pkgname=perl-${_cpan,,}
+pkgver=0.06
+pkgrel=4
+pkgdesc='Perl module providing cross-platform functions emulating common shell commands'
+arch=(any)
+url="https://metacpan.org/release/$_cpan"
+license=(GPL PerlArtistic)
+depends=(perl)
+options=(!emptydirs)
+_archive="$_cpan-$pkgver"
+source=("https://cpan.perl.org/modules/by-module/${_cpan%-*}/$_archive.tar.gz")
+sha256sums=('f3e4deef577944be46fa7af5ac118ac2828911788b01bc76a74495355616ecd1')
+
+build() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+ perl Makefile.PL
+ make
+}
+
+check() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1
+ make test
+}
+
+package() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+}
More information about the arch-commits
mailing list