[arch-commits] Commit in weechat/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sun May 29 11:51:33 UTC 2022
Date: Sunday, May 29, 2022 @ 11:51:33
Author: felixonmars
Revision: 1214463
archrelease: copy trunk to community-staging-x86_64
Added:
weechat/repos/community-staging-x86_64/
weechat/repos/community-staging-x86_64/PKGBUILD
(from rev 1214460, weechat/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: weechat/repos/community-staging-x86_64/PKGBUILD (from rev 1214460, weechat/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-05-29 11:51:33 UTC (rev 1214463)
@@ -0,0 +1,50 @@
+# Maintainer : Christian Rebischke <Chris.Rebischke at archlinux.org>
+# Maintainer : Caleb Maclennan <caleb at alerque.com>
+# Contributor: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: lucke <lucke at o2 dot pl>
+
+pkgname=weechat
+pkgver=3.5
+pkgrel=2
+pkgdesc="Fast, light and extensible IRC client (curses UI)"
+arch=('x86_64')
+url="https://www.weechat.org/"
+license=('GPL')
+depends=('gnutls' 'curl' 'libgcrypt')
+makedepends=('asciidoctor' 'cmake' 'aspell' 'guile' 'lua' 'perl' 'python'
+ 'ruby' 'tcl')
+optdepends=('aspell: spellchecker support'
+ 'guile: support for guile scripts'
+ 'lua: support for lua scripts'
+ 'perl: support for perl scripts'
+ 'python: support for python scripts'
+ 'ruby: support for ruby scripts'
+ 'tcl: support for tcl scripts')
+source=("https://www.weechat.org/files/src/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha512sums=('493be6219da4fa4b4862064de3d286d99d36018a61ba226f5abdc18c9ff43076d92f0b12fce96e04d31fed5c3931c7bf8615947cd19059dbf2c3aa75deead35f'
+ 'SKIP')
+b2sums=('4645d71a0f2742b0dbf0c905cfe085b6132ac4f1be6ec1056c432b2a1a7c7af2e62bf075a696732801be4fca3c45d7e3721a7fdaa9afac293623443793a27f26'
+ 'SKIP')
+validpgpkeys=('A9AB5AB778FA5C3522FD0378F82F4B16DEC408F8') # WeeChat (signing key) <webmaster at weechat.org>
+
+# cmake does not correctly handle CPPFLAGS, so kludge it in anyway:
+# https://gitlab.kitware.com/cmake/cmake/-/issues/12928
+CFLAGS+=" ${CPPFLAGS}"
+
+build() {
+ mkdir -p build
+ cd build
+ cmake -Wno-dev "${srcdir}/${pkgname}-${pkgver}" \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DENABLE_MAN=ON \
+ -DENABLE_DOC=ON \
+ -DENABLE_JAVASCRIPT=OFF \
+ -DENABLE_PHP=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="${pkgdir}" install
+}
More information about the arch-commits
mailing list