[arch-commits] Commit in haskell-monad-logger/repos (2 files)

[Felix Yan]

    Date: Thursday, September 1, 2022 @ 09:31:20
  Author: felixonmars
Revision: 1289869

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monad-logger/repos/community-staging-x86_64/
  haskell-monad-logger/repos/community-staging-x86_64/PKGBUILD
    (from rev 1289868, haskell-monad-logger/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-monad-logger/repos/community-staging-x86_64/PKGBUILD (from rev 1289868, haskell-monad-logger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-01 09:31:20 UTC (rev 1289869)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=monad-logger
+pkgname=haskell-monad-logger
+pkgver=0.3.37
+pkgrel=3
+pkgdesc="A class of monads which can log messages."
+url="https://github.com/snoyberg/monad-logger"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-fast-logger' 'haskell-lifted-base' 'haskell-monad-control' 'haskell-monad-loops'
+         'haskell-resourcet' 'haskell-stm-chans'
+         'haskell-transformers-base' 'haskell-transformers-compat' 'haskell-unliftio-core')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('4e1f4062df16b9b9c161fbba96eca753221081656df5259da9096b30dafe1a0aecd752d6f46fd2320eed35a8caefa3f6e0c4576b1cc563fcceeb1a34bac8f400')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -ftemplate_haskell
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}