[arch-commits] Commit in (4 files)

[Justin Kromlinger]

    Date: Thursday, September 1, 2022 @ 21:03:15
  Author: hashworks
Revision: 1290473

Initial commit

Added:
  opensearch-geospatial-plugin/
  opensearch-geospatial-plugin/repos/
  opensearch-geospatial-plugin/trunk/
  opensearch-geospatial-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Added: opensearch-geospatial-plugin/trunk/PKGBUILD
===================================================================
--- opensearch-geospatial-plugin/trunk/PKGBUILD	                        (rev 0)
+++ opensearch-geospatial-plugin/trunk/PKGBUILD	2022-09-01 21:03:15 UTC (rev 1290473)
@@ -0,0 +1,35 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+
+pkgname=opensearch-geospatial-plugin
+pkgver=2.2.1.0
+pkgrel=1
+_opensearchver=2.2.1
+_jdkver=11
+pkgdesc="OpenSearch Geospatial Plugin"
+arch=('x86_64')
+url="https://opensearch.org/docs/latest/dashboards/geojson-regionmaps/"
+license=('Apache')
+depends=("opensearch=${_opensearchver}")
+makedepends=("java-environment=${_jdkver}" 'unzip')
+source=(
+  "${pkgname}-${pkgver}.tar.gz::https://github.com/opensearch-project/geospatial/archive/${pkgver}.tar.gz"
+)
+sha256sums=('cb903c79fc35cff2a61581254815f7e0fc15b771247d9ae292406429ec758e1f')
+
+build() {
+  cd "geospatial-${pkgver}"
+  export JAVA_HOME="/usr/lib/jvm/java-${_jdkver}-openjdk"
+  export PATH="/usr/lib/jvm/java-${_jdkver}-openjdk/bin:$PATH"
+  export GRADLE_OPTS="-Dbuild.snapshot=false -Dopensearch.version=${_opensearchver}"
+  ./gradlew build \
+    --exclude-task ":jacocoTestReport" \
+    --exclude-task ":jacocoTestCoverageVerification"
+}
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-geospatial"
+  cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-geospatial"
+  unzip "${srcdir}/geospatial-${pkgver}/build/distributions/opensearch-geospatial-${pkgver}.zip"
+
+  install -Dm644 "${srcdir}/geospatial-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}