[arch-commits] Commit in python-natsort/trunk (PKGBUILD)

[David Runge]

    Date: Friday, September 2, 2022 @ 17:29:39
  Author: dvzrv
Revision: 1290941

upgpkg: python-natsort 8.2.0-1: Upgrade to 8.2.0.

Remove unnecessary quotes and curly braces.
Switch to PEP517.

Modified:
  python-natsort/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++----------------
 1 file changed, 21 insertions(+), 16 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-09-02 17:22:42 UTC (rev 1290940)
+++ PKGBUILD	2022-09-02 17:29:39 UTC (rev 1290941)
@@ -2,7 +2,7 @@
 
 _name=natsort
 pkgname=python-natsort
-pkgver=8.1.0
+pkgver=8.2.0
 pkgrel=1
 pkgdesc="Simple yet flexible natural sorting in Python"
 arch=(any)
@@ -9,28 +9,33 @@
 url="https://github.com/SethMMorton/natsort"
 license=(MIT)
 depends=(python)
-makedepends=(python-setuptools)
+makedepends=(python-build python-installer python-setuptools python-wheel)
 checkdepends=(python-hypothesis python-mock python-pytest-mock)
-optdepends=('python-fastnumbers: more efficient sorting'
-            'python-pyicu: sort in locale dependant manner')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
-sha512sums=('a065899b124e6a6ee8560ce1882650e35f0c36ddfd3c56462820886b076cd8cdb0121825e30e298af576e07915cc5bc1e90fe3f0b1f7bfb89f816c00665baa22')
-b2sums=('dcf9ffdb58cfe4d0f7ca0ed74701c8137a87716831dc747c5fb68d187a93c1b7414fa3625c0ed385e727e97c36feb99e9ecc6a41dd3d9da342d357646b5aaf32')
+optdepends=(
+  'python-fastnumbers: more efficient sorting'
+  'python-pyicu: sort in locale dependant manner'
+)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('d7e35c48ee36e69812c26b2cd333c57f1ec70c54017c4f51ed06dbb7619afc11cd1d589035faee700e1adf1e6b759b43ee497685fc88518be62c41957e15884e')
+b2sums=('d101ae2fa1cb009892e9712ece87d3825f3fca7970475e46176e5acbc29481ac79d491f1bae0721d85d3e67ecf39e5f54e2a984f0398356f32a5f0ec18a3e98d')
 
 build() {
-  cd "${_name}-$pkgver"
-  python setup.py build
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd "${_name}-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $_name-$pkgver
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  pytest -vv
 }
 
 package() {
-  cd "${_name}-$pkgver"
-  python setup.py install --optimize=1 --root="${pkgdir}"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 {CHANGELOG.md,README.rst} -t "${pkgdir}/usr/share/doc/${pkgname}"
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 {CHANGELOG.md,README.rst} -t "$pkgdir/usr/share/doc/$pkgname/"
 }