[arch-commits] Commit in haskell-vector-builder/repos (2 files)

[Felix Yan]

    Date: Saturday, September 3, 2022 @ 10:57:55
  Author: felixonmars
Revision: 1291612

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vector-builder/repos/community-staging-x86_64/
  haskell-vector-builder/repos/community-staging-x86_64/PKGBUILD
    (from rev 1291611, haskell-vector-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-vector-builder/repos/community-staging-x86_64/PKGBUILD (from rev 1291611, haskell-vector-builder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-03 10:57:55 UTC (rev 1291612)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vector-builder
+pkgname=haskell-vector-builder
+pkgver=0.3.8.4
+pkgrel=22
+pkgdesc="Vector builder"
+url="https://github.com/nikita-volkov/vector-builder"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-attoparsec' 'haskell-quickcheck-instances'
+             'haskell-rerebase' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b74a6b132b91fce38b69ba61223e5eaaca6350c1e9b08127c024daa9f7232663e1ad6382b6b30eac594fdea91085ed25b0c9fc3baac01592a6ad3fe71ae22ee2')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}