[arch-commits] Commit in haskell-zeromq4-haskell/repos (2 files)

[Felix Yan]

    Date: Monday, September 5, 2022 @ 23:39:15
  Author: felixonmars
Revision: 1293898

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-zeromq4-haskell/repos/community-staging-x86_64/
  haskell-zeromq4-haskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 1293897, haskell-zeromq4-haskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-zeromq4-haskell/repos/community-staging-x86_64/PKGBUILD (from rev 1293897, haskell-zeromq4-haskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-05 23:39:15 UTC (rev 1293898)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=zeromq4-haskell
+pkgname=haskell-zeromq4-haskell
+pkgver=0.8.0
+pkgrel=5
+pkgdesc="Bindings to ZeroMQ 4.x"
+url="https://gitlab.com/twittner/zeromq-haskell/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'zeromq' 'haskell-async' 'haskell-monad-control' 'haskell-transformers-base')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('d3be996589e126e30cb000545c56907e44a2a1d10960e4c7698b7941d0dff66b')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -d semigroups $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --datasubdir=haskell-zeromq4-haskell --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}