[arch-commits] Commit in haskell-tidal/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 6, 2022 @ 00:14:06
  Author: felixonmars
Revision: 1294076

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tidal/repos/community-staging-x86_64/
  haskell-tidal/repos/community-staging-x86_64/PKGBUILD
    (from rev 1294075, haskell-tidal/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-tidal/repos/community-staging-x86_64/PKGBUILD (from rev 1294075, haskell-tidal/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-06 00:14:06 UTC (rev 1294076)
@@ -0,0 +1,51 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=tidal
+pkgname=haskell-tidal
+pkgver=1.8.1
+pkgrel=5
+pkgdesc="A domain specific language for live coding pattern."
+arch=(x86_64)
+url="https://tidalcycles.org/"
+license=(GPL3)
+groups=(pro-audio)
+depends=(ghc ghc-libs glibc haskell-bifunctors haskell-clock
+haskell-colour haskell-hosc haskell-mwc-random haskell-network
+haskell-primitive haskell-random haskell-vector supercollider)
+checkdepends=(haskell-microspec)
+optdepends=('sc3-plugins: Examples using special UGens')
+conflicts=(tidalcycles)
+replaces=(tidalcycles)
+source=("https://hackage.haskell.org/packages/archive/$_name/$pkgver/$_name-$pkgver.tar.gz")
+sha512sums=('297be8b76b4574b91e2c670a2a09a128ccfb3a19f023139b70310f2de5f0de8af0d02d1039ccd14ea9f39075f11025bf911007d654d19a2717ed1ee3c38ad21d')
+b2sums=('5ba2c87b966e4e5e720c1296eaad71b55faaf08fb6e65fa617d2b47bec4eb9d23715aff2ea78c31d05ae516e221d4f6411c4e58ff310d484b4f5dd1535bda5fe')
+
+build() {
+  cd $_name-$pkgver
+  runhaskell Setup configure -O \
+                             --enable-shared \
+                             --enable-executable-dynamic \
+                             --disable-library-vanilla \
+                             --prefix=/usr \
+                             --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname \
+                             --enable-tests \
+                             --dynlibdir=/usr/lib \
+                             --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_name-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_name-$pkgver
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -vDm 744 register.sh "$pkgdir/usr/share/haskell/register/$pkgname.sh"
+  install -vDm 744 unregister.sh "$pkgdir/usr/share/haskell/unregister/$pkgname.sh"
+}