[arch-commits] Commit in haskell-parsers/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 6, 2022 @ 07:09:28
  Author: felixonmars
Revision: 1294295

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-parsers/repos/community-staging-x86_64/
  haskell-parsers/repos/community-staging-x86_64/PKGBUILD
    (from rev 1294294, haskell-parsers/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-parsers/repos/community-staging-x86_64/PKGBUILD (from rev 1294294, haskell-parsers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-06 07:09:28 UTC (rev 1294295)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=parsers
+pkgname=haskell-parsers
+pkgver=0.12.11
+pkgrel=33
+pkgdesc="Parsing combinators"
+url="https://github.com/ekmett/parsers/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-orphans' 'haskell-charset'
+         'haskell-scientific' 'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7ffa8b092aa731dc263151f755b52126924a8dd0a6c51aa52b044937976ad6410dd0755af5d361f5255c212e6cadc5793d15fa3a3fe26514c1324eeee71b4019')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+        -fbinary -fparsec -fattoparsec
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}