[arch-commits] Commit in deepin-album/repos (2 files)

[Antonio Rojas]

    Date: Thursday, September 8, 2022 @ 12:40:56
  Author: arojas
Revision: 1296787

archrelease: copy trunk to community-staging-x86_64

Added:
  deepin-album/repos/community-staging-x86_64/
  deepin-album/repos/community-staging-x86_64/PKGBUILD
    (from rev 1296786, deepin-album/trunk/PKGBUILD)

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Copied: deepin-album/repos/community-staging-x86_64/PKGBUILD (from rev 1296786, deepin-album/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-09-08 12:40:56 UTC (rev 1296787)
@@ -0,0 +1,33 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=deepin-album
+pkgver=5.10.5
+pkgrel=2
+pkgdesc='A fashion photo manager for viewing and organizing pictures'
+arch=('x86_64')
+url="https://github.com/linuxdeepin/deepin-album"
+license=('GPL3')
+depends=('deepin-qt5integration' 'deepin-image-editor' 'ffmpegthumbnailer' 'gio-qt' 'hicolor-icon-theme' 'udisks2-qt5')
+makedepends=('cmake' 'ninja' 'qt5-tools')
+groups=('deepin-extra')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxdeepin/deepin-album/archive/$pkgver.tar.gz")
+sha512sums=('a13867805489e9c0c564b167a1a3c84b7a9692e3feb451efdc0e7cc715626ce3f8ba007c08572bef087dd31b32dfe4c94ec71fcf39f922cf037acb1a5e79e07e')
+options=(!lto)
+
+prepare() {
+  cd deepin-album-$pkgver
+
+  # Our build of freeimage disabled support for these formats
+  sed -i '/FIF_FAXG3/d' libUnionImage/UnionImage/unionimage.cpp
+}
+
+build() {
+  cd deepin-album-$pkgver
+  cmake . -GNinja -DCMAKE_INSTALL_PREFIX=/usr
+  ninja
+}
+
+package() {
+  cd deepin-album-$pkgver
+  DESTDIR="$pkgdir" ninja install
+}