[arch-commits] Commit in ruby-digest/repos/community-testing-x86_64 (2 files)

[Andreas Schleifer]

    Date: Thursday, September 8, 2022 @ 21:27:52
  Author: segaja
Revision: 1296924

archrelease: copy trunk to community-testing-x86_64

Added:
  ruby-digest/repos/community-testing-x86_64/PKGBUILD
    (from rev 1296923, ruby-digest/trunk/PKGBUILD)
Deleted:
  ruby-digest/repos/community-testing-x86_64/PKGBUILD

----------+
 PKGBUILD |  154 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 77 insertions(+), 77 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-09-08 21:27:41 UTC (rev 1296923)
+++ PKGBUILD	2022-09-08 21:27:52 UTC (rev 1296924)
@@ -1,77 +0,0 @@
-# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
-
-_gemname='digest'
-pkgname="ruby-${_gemname}"
-pkgver=3.1.0
-pkgrel=2
-pkgdesc='Provides a framework for message digest libraries'
-arch=('x86_64')
-url="https://github.com/ruby/${_gemname}"
-license=('BSD' 'RUBY')
-depends=('ruby')
-makedepends=('ruby-rake' 'ruby-rake-compiler')
-#checkdepends=('ruby-digest')
-options=(!emptydirs)
-source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
-sha512sums=('2a5d58d4b92f5391f55e43405d515ea045f8d0b0b09602ac8dc57e784b42787956904a8c51ffba026d2f0ecc2efff17a1d39c632d59afaf7941b455d8b2dcd39')
-
-prepare() {
-  cd "${_gemname}-${pkgver}"
-
-  # update gemspec/Gemfile to allow newer version of the dependencies
-  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
-}
-
-build() {
-  cd "${_gemname}-${pkgver}"
-
-  rake compile
-  rake build
-}
-
-#check() {
-#  cd "${_gemname}-${pkgver}"
-#
-#  rake check
-#  rake test
-#}
-
-package() {
-  cd "${_gemname}-${pkgver}"
-
-  local _gemdir="$(gem env gemdir)"
-  local _platform="$(gem env platform | cut -d':' -f2)"
-  local _extension_api_version="$(ruby -e 'puts Gem.extension_api_version')"
-
-  gem install \
-    --local \
-    --verbose \
-    --ignore-dependencies \
-    --no-user-install \
-    --install-dir "${pkgdir}/${_gemdir}" \
-    --bindir "${pkgdir}/usr/bin" \
-    "pkg/${_gemname}-${pkgver}.gem"
-
-  install --verbose --directory --mode=0755 \
-    "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}" \
-    "${pkgdir}${_gemdir}/specifications/default"
-
-  mv --verbose "${_gemname}.gemspec" "${pkgdir}${_gemdir}/specifications/default/${_gemname}-${pkgver}.gemspec"
-  mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}.rb" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}.rb"
-  mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}"
-  mv --verbose "${pkgdir}${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/${_gemname}.so" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}/${_gemname}.so"
-  mv --verbose "${pkgdir}${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/${_gemname}" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}/${_gemname}"
-
-  # remove unrepreducible files
-  rm --force --recursive --verbose \
-    "${pkgdir}${_gemdir}/cache/" \
-    "${pkgdir}${_gemdir}/build_info/" \
-    "${pkgdir}${_gemdir}/extensions/" \
-    "${pkgdir}${_gemdir}/gems/" \
-    "${pkgdir}${_gemdir}/plugins/" \
-    "${pkgdir}${_gemdir}/specifications/${_gemname}-${pkgver}.gemspec" \
-    "${pkgdir}${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
-
-  install --verbose -D --mode=0644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
-}

Copied: ruby-digest/repos/community-testing-x86_64/PKGBUILD (from rev 1296923, ruby-digest/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-09-08 21:27:52 UTC (rev 1296924)
@@ -0,0 +1,77 @@
+# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
+
+_gemname='digest'
+pkgname="ruby-${_gemname}"
+pkgver=3.1.0
+pkgrel=3
+pkgdesc='Provides a framework for message digest libraries'
+arch=('x86_64')
+url="https://github.com/ruby/${_gemname}"
+license=('BSD' 'RUBY')
+depends=('ruby')
+makedepends=('ruby-rake' 'ruby-rake-compiler')
+checkdepends=('ruby-digest')
+options=(!emptydirs)
+source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('2a5d58d4b92f5391f55e43405d515ea045f8d0b0b09602ac8dc57e784b42787956904a8c51ffba026d2f0ecc2efff17a1d39c632d59afaf7941b455d8b2dcd39')
+
+prepare() {
+  cd "${_gemname}-${pkgver}"
+
+  # update gemspec/Gemfile to allow newer version of the dependencies
+  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
+}
+
+build() {
+  cd "${_gemname}-${pkgver}"
+
+  rake compile
+  rake build
+}
+
+check() {
+  cd "${_gemname}-${pkgver}"
+
+  rake check
+  rake test
+}
+
+package() {
+  cd "${_gemname}-${pkgver}"
+
+  local _gemdir="$(gem env gemdir)"
+  local _platform="$(gem env platform | cut -d':' -f2)"
+  local _extension_api_version="$(ruby -e 'puts Gem.extension_api_version')"
+
+  gem install \
+    --local \
+    --verbose \
+    --ignore-dependencies \
+    --no-user-install \
+    --install-dir "${pkgdir}/${_gemdir}" \
+    --bindir "${pkgdir}/usr/bin" \
+    "pkg/${_gemname}-${pkgver}.gem"
+
+  install --verbose --directory --mode=0755 \
+    "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}" \
+    "${pkgdir}${_gemdir}/specifications/default"
+
+  mv --verbose "${_gemname}.gemspec" "${pkgdir}${_gemdir}/specifications/default/${_gemname}-${pkgver}.gemspec"
+  mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}.rb" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}.rb"
+  mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}"
+  mv --verbose "${pkgdir}${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/${_gemname}.so" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}/${_gemname}.so"
+  mv --verbose "${pkgdir}${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/${_gemname}" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}/${_gemname}"
+
+  # remove unrepreducible files
+  rm --force --recursive --verbose \
+    "${pkgdir}${_gemdir}/cache/" \
+    "${pkgdir}${_gemdir}/build_info/" \
+    "${pkgdir}${_gemdir}/extensions/" \
+    "${pkgdir}${_gemdir}/gems/" \
+    "${pkgdir}${_gemdir}/plugins/" \
+    "${pkgdir}${_gemdir}/specifications/${_gemname}-${pkgver}.gemspec" \
+    "${pkgdir}${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
+
+  install --verbose -D --mode=0644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
+}