[arch-commits] Commit in qt6-multimedia/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Friday, September 9, 2022 @ 12:09:20
  Author: arojas
Revision: 455712

archrelease: copy trunk to testing-x86_64

Added:
  qt6-multimedia/repos/testing-x86_64/
  qt6-multimedia/repos/testing-x86_64/PKGBUILD
    (from rev 455711, qt6-multimedia/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: qt6-multimedia/repos/testing-x86_64/PKGBUILD (from rev 455711, qt6-multimedia/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-09-09 12:09:20 UTC (rev 455712)
@@ -0,0 +1,35 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=qt6-multimedia
+_qtver=6.3.2
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Classes for audio, video, radio and camera functionality'
+depends=(qt6-base gst-plugins-base)
+makedepends=(cmake ninja qt6-declarative qt6-shadertools libpulse)
+optdepends=('qt6-declarative: QML bindings'
+            'gst-plugins-good: camera support, additional plugins'
+            'gst-plugins-bad: camera support, additional plugins'
+            'gst-plugins-ugly: additional plugins'
+            'gst-libav: ffmpeg plugin')
+groups=(qt6)
+options=(debug)
+_pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
+source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
+sha256sums=('7f6829aa4509e23a9804260b6d859531b20a806c4dadedfd2c0c7dd314c01c43')
+
+build() {
+  cmake -B build -S $_pkgfn -G Ninja
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+}