[arch-commits] Commit in lv2/trunk (PKGBUILD)

[David Runge]

    Date: Saturday, September 10, 2022 @ 08:28:09
  Author: dvzrv
Revision: 1298789

upgpkg: lv2 1.18.10-1: Upgrade to 1.18.10.

Add back gtk2 to makedepends: https://gitlab.com/lv2/lv2/-/issues/56
Split out example plugins and documentation to split packages.

Modified:
  lv2/trunk/PKGBUILD

----------+
 PKGBUILD |   76 ++++++++++++++++++++++++++++++++++++++++++++++---------------
 1 file changed, 58 insertions(+), 18 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-09-10 08:25:42 UTC (rev 1298788)
+++ PKGBUILD	2022-09-10 08:28:09 UTC (rev 1298789)
@@ -1,8 +1,9 @@
 # Maintainer: David Runge <dvzrv at archlinux.org>
 # Contributor: Ray Rashif <schiv at archlinux.org>
 
-pkgname=lv2
-pkgver=1.18.8
+pkgbase=lv2
+pkgname=(lv2 lv2-docs lv2-example-plugins)
+pkgver=1.18.10
 pkgrel=1
 pkgdesc="Plugin standard for audio systems"
 arch=(x86_64)
@@ -13,6 +14,7 @@
   codespell
   doxygen
   flake8
+  gtk2
   libsamplerate
   libsndfile
   meson
@@ -26,25 +28,26 @@
   serd
   sord
 )
-optdepends=(
-  'sord: for lv2_validate'
-  'libsamplerate: for eg-sampler.lv2'
-  'libsndfile: for eg-sampler.lv2'
-  'python-lxml: for lv2specgen.py'
-  'python-markdown: for lv2specgen.py'
-  'python-pygments: for lv2specgen.py'
-  'python-rdflib: for lv2specgen.py'
-)
 options=(debug)
-source=(https://lv2plug.in/spec/$pkgname-$pkgver.tar.xz{,.sig})
-sha512sums=('9925290818bd683200bc738e3e9342b946fe82a04d983e89c240ae70b9053a7a59a8d505c522fe7af5b804adeba00fdf94403bd34844ce11e26cc1ff62c2f254'
+source=(https://lv2plug.in/spec/$pkgbase-$pkgver.tar.xz{,.sig})
+sha512sums=('ab4bcf593f633b1ed16c0eb6aa4525458a00655ef9c87619bf85eaa966f8fd094a8e871b825f679e0d97923f8bbbf11841ff467022390ca2f1a5b5f66ccd5d1b'
             'SKIP')
-b2sums=('b9d6480286f0709d3e7ddd9444c092e4e1e108ed384a8cdc7991ec870e8374869bab21e09ebebad4c59445ec3a90ddd05bf2c461a1c9aeb986f68d84a937bbbd'
+b2sums=('72f9bc50ebac5d71279e0616bb1eb3c2a6748a28ff68988294135b18c7adc68c46a52b4698faf79f633768bf850d5052128a9f84b90aa9b5f9a56721acaf04c3'
         'SKIP')
 validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d at drobilla.net>
 
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
 build() {
-  arch-meson $pkgname-$pkgver build
+  arch-meson $pkgbase-$pkgver build
   meson compile -C build
 }
 
@@ -52,9 +55,46 @@
   meson test -C build
 }
 
-package() {
+package_lv2() {
+  optdepends=(
+    'lv2-docs: for developer documentation'
+    'lv2-example-plugins: for example plugins'
+    'python-lxml: for lv2specgen.py'
+    'python-markdown: for lv2specgen.py'
+    'python-pygments: for lv2specgen.py'
+    'python-rdflib: for lv2specgen.py'
+    'sord: for lv2_validate'
+  )
+
   meson install -C build --destdir "$pkgdir"
-  install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
-  install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
+
+  (
+    cd "$pkgdir"
+    _pick lv2-docs usr/share/doc/lv2/
+    _pick lv2-example-plugins usr/lib/lv2/eg-*
+  )
+
+  install -vDm 644 $pkgbase-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 $pkgbase-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
 }
+
+package_lv2-docs() {
+  pkgdesc+=" - documentation"
+
+  mv -v $pkgname/* "$pkgdir"
+  install -vDm 644 $pkgbase-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
+}
+
+package_lv2-example-plugins() {
+  pkgdesc+=" - example plugins"
+  depends=(libsamplerate libsndfile lv2-host)
+  optdepends=(
+    'gtk2: for eg-sampler.lv2 and eg-scope.lv2'
+  )
+  groups=(lv2-plugins pro-audio)
+
+  mv -v $pkgname/* "$pkgdir"
+  install -vDm 644 $pkgbase-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
+}
+
 # vim:set ts=2 sw=2 et: