[arch-general] gnucash in [extra]

[Ng Oon-Ee]

Hi, I noticed that said package is out of date, am attaching a slightly
updated PKGBUILD for the latest version here (compiles and runs fine on
my machine x86_64).

Normally I'd wait, but the maintainer is Aaron and as I understand he's
not very active round these parts anymore.

P.S. - hope the attachment gets through. If not, all I did was remove
the patch, add libdbi-drivers to depends, and add --enable-dbi to the
configure line
-------------- next part --------------
# $Id: PKGBUILD 101470 2010-11-29 10:30:25Z heftig $
# Maintainer: Aaron Griffin <aaron at archlinux.org>
# Contributor: Mark Schneider <queueRAM at gmail.com>

pkgname=gnucash
pkgver=2.4.0
pkgrel=1
pkgdesc="A personal and small-business financial-accounting application"
arch=('i686' 'x86_64')
url="http://www.gnucash.org"
license=("GPL")
depends=('gtkhtml>=3.32.1' 'slib' 'goffice>=0.8.12' 'guile' 'libofx' 'libgnomeui>=2.24.4' 'hicolor-icon-theme' 'libdbi-drivers')
makedepends=('intltool')
optdepends=('evince: for print preview'
            'gnucash-docs: (AUR) for user documentation'
            'perl-finance-quote: for stock information lookups'
            'perl-date-manip: for stock information lookups')
options=('!libtool' '!makeflags')
install=gnucash.install
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz)
md5sums=('fb7b4ebebf26e8504ea08787db123d5e')
build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr --mandir=/usr/share/man \
    --sysconfdir=/etc --libexecdir=/usr/lib --enable-ofx \
    --enable-dbi
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${pkgdir} install

  install -dm755 ${pkgdir}/usr/share/gconf/schemas
  gconf-merge-schema ${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas --domain gnucash ${pkgdir}/etc/gconf/schemas/*.schemas
  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}