[aur-general] Orphaned Banshee in Extra Repository Outdated

[pauline martin]

I was looking in the repositories earlier and noticed that the banshee in
there is flagged out of date.  Therefore, I went and found the tarball and
with assistance from a few other PKGBUILDS was able to get it to build.
Here is the PKGBUILD:

# Contributor: Pauline123 (Pauline Martin) <321eniluap at gmail dot com>
# Contributor: György Balló <ballogy at freestart.hu>
# Contributor: Matthias Sobczyk <matthias.sobczyk at googlemail.com>
# Contributor: György Balló <ballogy at freestart.hu>

pkgname=banshee
pkgver=2.1.0
_pkgver=2.1
pkgrel=3
pkgdesc="Music management and playback for GNOME (development release)"
arch=('i686' 'x86_64')
url="http://banshee.fm/"
license=('MIT')
depends=('boo>=0.8.1' 'dbus-sharp-glib>=0.5' 'desktop-file-utils'
'gconf-sharp'
'gdata-sharp>=1.4' 'gkeyfile-sharp>=0.1' 'gstreamer0.10-base-plugins'
'gtk-sharp-beans>=2.14.0' 'gudev-sharp>=0.1' 'hicolor-icon-theme'
'libgpod>=0.7.95' 'libmtp>=0.2.0' 'libwebkit>=1.2.2' 'libxxf86vm'
'musicbrainz'
'media-player-info' 'mono-addins>=0.3.1' 'mono-zeroconf>=0.8.0'
'notify-sharp-svn' 'shared-mime-info' 'taglib-sharp>=2.0.3.7'
'xdg-utils' 'hal')
makedepends=('intltool' 'gnome-doc-utils')
optdepends=('brasero: CD burning'
            'gstreamer0.10-good-plugins: Extra media codecs'
            'gstreamer0.10-ugly-plugins: Extra media codecs'
            'gstreamer0.10-bad-plugins: Extra media codecs'
            'gstreamer0.10-ffmpeg: Extra media codecs')
provides=('banshee')
conflicts=('banshee' 'banshee-1-svn' 'banshee-git')
options=('!libtool')
install=${pkgname}.install
source=(
http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${_pkgver}/${pkgname}-${pkgver}.tar.bz2
)
md5sums=('4cbec8d2640be5b9b6157d3245969153')

build() {
  export MONO_SHARED_DIR="${srcdir}/.wabi"
  mkdir -p "${MONO_SHARED_DIR}"

  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-docs \
              --disable-static \
              --disable-scrollkeeper \
              --with-vendor-build-id=ArchLinux
  make
}

package() {
  export MONO_SHARED_DIR="${srcdir}/.wabi"
  mkdir -p "${MONO_SHARED_DIR}"

  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}


Here is the banshee.install that goes with it:

pkgname=banshee

post_install() {
  update-desktop-database -q
  update-mime-database usr/share/mime &> /dev/null
  xdg-icon-resource forceupdate
}

post_upgrade() {
  post_install $1
}

post_remove() {
  post_install $1
}

Hope this was of some help. :)
Pauline123