[aur-general] PKGBUILD review request

[Lone_Wolf]

On 07-02-2019 23:13, Josef Miegl wrote:
> I've been trying to improve my AUR packages for the last few days. I'm
> still a beginner in package maintaining so I would like to have some
> feedback on some of my PKGBUILDs. I would love to hear everything that
> is wrong about them. Thanks!
>
>
> # Maintainer: Josef Miegl <josef at miegl.cz>
>
> pkgname=osmo-bsc-git
> pkgver=1.4.0.15.g7cfdbe727
> pkgrel=1
> pkgdesc="Open Source BSC (GSM Base Station Controller) with A-bis/IP and A/IP interface"
> url="https://osmocom.org/projects/osmobsc"
> arch=('i686' 'x86_64' 'aarch64' 'armv7h')
> license=(GPL)
> depends=('libosmocore' 'libosmo-abis' 'libosmo-sccp' 'osmo-mgw')
> makedepends=('git' 'talloc')
> provides=("${pkgname%-git}")
> conflicts=("${pkgname%-git}")
> backup=('etc/osmocom/osmo-bsc.cfg')
> source=("git+https://git.osmocom.org/${pkgname%-git}")
> sha256sums=('SKIP')
>
> pkgver() {
>    cd "${srcdir}/${pkgname%-git}"
>    echo $(git describe --always | sed 's/-/./g')
> }
>
> build() {
>    cd "${srcdir}/${pkgname%-git}"
>    autoreconf -i
>    ./configure --prefix=/usr --sysconfdir=/etc
>    make
> }

On archlinux we usually need to add the -f / --force option to autoreconf.

Also autoreconf does change source files. That should be done in 
prepare() function, not build() .

LW

> package() {
>    cd "${srcdir}/${pkgname%-git}"
>    make DESTDIR=${pkgdir} install
> }
>
> # vim:set ts=2 sw=2 et: