[arch-commits] Commit in (4 files)
Felix Yan
fyan at nymeria.archlinux.org
Fri Mar 14 03:24:05 UTC 2014
Date: Friday, March 14, 2014 @ 04:24:04
Author: fyan
Revision: 207731
addpkg: python-pycparser 2.10-3
- as dependency of python-cffi
Added:
python-pycparser/
python-pycparser/repos/
python-pycparser/trunk/
python-pycparser/trunk/PKGBUILD
----------+
PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
Added: python-pycparser/trunk/PKGBUILD
===================================================================
--- python-pycparser/trunk/PKGBUILD (rev 0)
+++ python-pycparser/trunk/PKGBUILD 2014-03-14 03:24:04 UTC (rev 207731)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Justin Dray <justin at dray.be>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: lang2 <wenzhi.liang at gmail.com>
+
+pkgbase=python-pycparser
+pkgname=(python-pycparser python2-pycparser)
+pkgver=2.10
+pkgrel=3
+pkgdesc='C parser and AST generator written in Python'
+url='https://github.com/eliben/pycparser'
+makedepends=('python-ply' 'python2-ply' 'git')
+arch=('any')
+license=('BSD')
+source=('https://github.com/eliben/pycparser/archive/release_v2.10.zip')
+sha256sums=('1217244f882c330782f4762a1fb37cef21a929ce0123ac388e7e367c35ddbae3')
+
+prepare() {
+ cp -r pycparser-release_v${pkgver}{,-py2}
+}
+
+build() {
+ cd pycparser-release_v${pkgver}
+ python setup.py build
+
+ cd pycparser
+ python _build_tables.py
+
+ cd "$srcdir/pycparser-release_v${pkgver}-py2"
+ python2 setup.py build
+
+ cd pycparser
+ python2 _build_tables.py
+}
+
+package_python-pycparser() {
+ depends=('python-ply')
+
+ cd pycparser-release_v${pkgver}
+
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-pycparser() {
+ depends=('python2-ply')
+
+ cd pycparser-release_v${pkgver}-py2
+
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
Property changes on: python-pycparser/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list