[arch-commits] Commit in (4 files)
Felix Yan
fyan at nymeria.archlinux.org
Fri Mar 14 03:33:03 UTC 2014
Date: Friday, March 14, 2014 @ 04:33:03
Author: fyan
Revision: 207733
addpkg: python-cffi 0.8.2-3
- as dependency of python-cryptography
Added:
python-cffi/
python-cffi/repos/
python-cffi/trunk/
python-cffi/trunk/PKGBUILD
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Added: python-cffi/trunk/PKGBUILD
===================================================================
--- python-cffi/trunk/PKGBUILD (rev 0)
+++ python-cffi/trunk/PKGBUILD 2014-03-14 03:33:03 UTC (rev 207733)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: lilydjwg <lilydjwg at gmail.com>
+
+_name=cffi
+pkgbase=python-$_name
+pkgname=(python-$_name python2-$_name)
+pkgver=0.8.2
+pkgrel=3
+pkgdesc="Foreign Function Interface for Python calling C code"
+arch=('i686' 'x86_64')
+url="http://cffi.readthedocs.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pycparser' 'python2-pycparser')
+md5sums=('37fc88c62f40d04e8a18192433f951ec')
+source=("http://pypi.python.org/packages/source/c/${_name}/${_name}-${pkgver}.tar.gz")
+
+prepare() {
+ cp -r $_name-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir/$_name-$pkgver"
+ python3 setup.py build
+
+ cd "$srcdir/$_name-$pkgver-py2"
+ python2 setup.py build
+}
+
+package_python-cffi() {
+ depends=('python' 'python-pycparser')
+
+ cd "$srcdir/$_name-$pkgver"
+ python3 setup.py install --root="$pkgdir/" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-cffi() {
+ depends=('python2' 'python2-pycparser')
+
+ cd "$srcdir/$_name-$pkgver-py2"
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
Property changes on: python-cffi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list