[arch-commits] Commit in (4 files)

[Timothy Redaelli]

    Date: Sunday, August 16, 2015 @ 13:14:31
  Author: tredaelli
Revision: 138405

New package: syncthing-inotify

Added:
  syncthing-inotify/
  syncthing-inotify/repos/
  syncthing-inotify/trunk/
  syncthing-inotify/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: syncthing-inotify/trunk/PKGBUILD
===================================================================
--- syncthing-inotify/trunk/PKGBUILD	                        (rev 0)
+++ syncthing-inotify/trunk/PKGBUILD	2015-08-16 11:14:31 UTC (rev 138405)
@@ -0,0 +1,43 @@
+# $Id:$
+# Maintainer: Timothy Redaelli <timothy.redaelli at gmail.com>
+# Contributor: Stefan Tatschner <stefan at sevenbyte.org>
+
+pkgname=syncthing-inotify
+pkgver=0.6.7
+pkgrel=1
+pkgdesc="Inotify file watcher for Syncthing"
+url="https://github.com/syncthing/syncthing-inotify"
+license=('MPL')
+arch=('i686' 'x86_64')
+depends=('syncthing')
+makedepends=('git' 'go' 'godep')
+source=("$pkgname-$pkgver::git+https://github.com/syncthing/syncthing-inotify.git#tag=v${pkgver}")
+sha256sums=('SKIP')
+
+prepare() {
+    cd "${srcdir}"
+    mkdir -p "src/github.com/syncthing"
+    mv "${pkgname}-${pkgver}" "src/github.com/syncthing/${pkgname}"
+}
+
+build() {
+    export GOPATH="${srcdir}"
+    cd "${srcdir}/src/github.com/syncthing/${pkgname}"
+    go get
+    go build
+}
+
+check() {
+    export GOPATH="${srcdir}"
+    cd "${srcdir}/src/github.com/syncthing/${pkgname}"
+    go test
+}
+
+package() {
+    cd "${srcdir}/src/github.com/syncthing/${pkgname}"
+    install -Dm755 ${pkgname} "${pkgdir}/usr/bin/${pkgname}"
+    install -Dm644 "etc/linux-systemd/user/syncthing-inotify.service" "${pkgdir}/usr/lib/systemd/user/syncthing-inotify.service"
+    install -Dm644 "etc/linux-systemd/system/syncthing-inotify at .service" "${pkgdir}/usr/lib/systemd/system/syncthing-inotify at .service"
+    install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}