[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, August 23, 2015 @ 06:08:04
  Author: fyan
Revision: 138656

addpkg: python-packaging 15.3-1

Added:
  python-packaging/
  python-packaging/repos/
  python-packaging/trunk/
  python-packaging/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: python-packaging/trunk/PKGBUILD
===================================================================
--- python-packaging/trunk/PKGBUILD	                        (rev 0)
+++ python-packaging/trunk/PKGBUILD	2015-08-23 04:08:04 UTC (rev 138656)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-packaging
+pkgname=(python-packaging python2-packaging)
+_pkgname=packaging
+pkgver=15.3
+pkgrel=1
+pkgdesc="Core utilities for Python packages"
+arch=('any')
+url="https://github.com/pypa/packaging"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-pretend' 'python2-pretend' 'python-coverage' 'python2-coverage')
+source=("git+https://github.com/pypa/packaging.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a $_pkgname{,-py2}
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py build
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py ptr
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py ptr
+}
+
+package_python-packaging() {
+  depends=('python')
+
+  cd "${srcdir}/${_pkgname}"
+  python setup.py egg_info
+  python setup.py install --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-packaging() {
+  depends=('python2')
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py egg_info
+  python2 setup.py install --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-packaging/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property