[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, December 4, 2015 @ 04:35:13
  Author: fyan
Revision: 148264

addpkg: python-iocapture 0.1.2-1

Added:
  python-iocapture/
  python-iocapture/repos/
  python-iocapture/trunk/
  python-iocapture/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: python-iocapture/trunk/PKGBUILD
===================================================================
--- python-iocapture/trunk/PKGBUILD	                        (rev 0)
+++ python-iocapture/trunk/PKGBUILD	2015-12-04 03:35:13 UTC (rev 148264)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-iocapture
+pkgname=('python-iocapture' 'python2-iocapture')
+pkgver=0.1.2
+pkgrel=1
+pkgdesc="Capture stdout, stderr easily."
+arch=('any')
+license=('MIT')
+url="https://github.com/oinume/iocapture"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-flexmock'
+              'python2-flexmock' 'python-pytest-cov' 'python2-pytest-cov'
+              'python-six' 'python2-six')
+source=("git+https://github.com/oinume/iocapture.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a iocapture{,-py2}
+}
+
+build() {
+  cd "$srcdir/iocapture"
+  python setup.py build
+
+  cd "$srcdir/iocapture-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/iocapture"
+  python setup.py ptr
+
+  cd "$srcdir/iocapture-py2"
+  python2 setup.py ptr
+}
+
+package_python-iocapture() {
+  depends=('python')
+
+  cd iocapture
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-iocapture() {
+  depends=('python2')
+
+  cd iocapture-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-iocapture/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property