[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, December 4, 2015 @ 04:37:44
  Author: fyan
Revision: 148268

addpkg: python-argh 0.26.1.20151013-1

Added:
  python-argh/
  python-argh/repos/
  python-argh/trunk/
  python-argh/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-argh/trunk/PKGBUILD
===================================================================
--- python-argh/trunk/PKGBUILD	                        (rev 0)
+++ python-argh/trunk/PKGBUILD	2015-12-04 03:37:44 UTC (rev 148268)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Francois Boulogne <fboulogne at april dot org>
+
+pkgname=python-argh
+pkgver=0.26.1.20151013
+_commit=994dcb479a0195621b4a62f68a2ce9e990e28051
+pkgrel=1
+pkgdesc="An unobtrusive argparse wrapper with natural syntax"
+arch=(any)
+url="https://pypi.python.org/pypi/argh"
+license=('LGPL3')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock'
+              'python-iocapture' 'python2-iocapture')
+source=("git+https://github.com/neithere/argh.git#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a argh{,-py2}
+}
+
+build() {
+  cd "$srcdir/argh"
+  python setup.py build
+
+  cd "$srcdir/argh-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/argh"
+  py.test
+
+  cd "$srcdir/argh-py2"
+  LC_CTYPE=en_US.UTF-8 py.test2
+}
+
+package_python-argh() {
+  depends=('python')
+
+  cd "$srcdir/argh"
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-argh() {
+  depends=('python2')
+
+  cd "$srcdir/argh-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-argh/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property