[arch-commits] Commit in (4 files)

[Anatol Pomozov]

    Date: Wednesday, October 7, 2015 @ 17:14:24
  Author: anatolik
Revision: 143300

Add python-txaio

Added:
  python-txaio/
  python-txaio/repos/
  python-txaio/trunk/
  python-txaio/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-txaio/trunk/PKGBUILD
===================================================================
--- python-txaio/trunk/PKGBUILD	                        (rev 0)
+++ python-txaio/trunk/PKGBUILD	2015-10-07 15:14:24 UTC (rev 143300)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+
+pkgbase=python-txaio
+pkgname=(python-txaio python2-txaio)
+pkgver=2.0.2
+pkgrel=1
+pkgdesc='Utilities to support code that runs unmodified on Twisted and asyncio'
+arch=(any)
+url='https://github.com/tavendo/txaio'
+license=(MIT)
+makedepends=(python-setuptools python2-setuptools)
+source=(https://pypi.python.org/packages/source/t/txaio/txaio-$pkgver.tar.gz)
+sha1sums=('b526ccbb20f1ea5c00d8846dcba272eab535d5da')
+
+prepare() {
+  cp -a txaio-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/txaio-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/txaio-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/txaio-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/txaio-$pkgver-py2"
+  python2 setup.py test
+}
+
+package_python-txaio() {
+  depends=(python python-six)
+
+  cd "$srcdir/txaio-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-txaio() {
+  depends=(python2 python2-six)
+
+  cd "$srcdir/txaio-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-txaio/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property