[arch-commits] Commit in (4 files)
Anatol Pomozov
anatolik at archlinux.org
Wed Oct 7 16:30:07 UTC 2015
Date: Wednesday, October 7, 2015 @ 18:30:06
Author: anatolik
Revision: 143302
Add python-mpi4py
Added:
python-mpi4py/
python-mpi4py/repos/
python-mpi4py/trunk/
python-mpi4py/trunk/PKGBUILD
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Added: python-mpi4py/trunk/PKGBUILD
===================================================================
--- python-mpi4py/trunk/PKGBUILD (rev 0)
+++ python-mpi4py/trunk/PKGBUILD 2015-10-07 16:30:06 UTC (rev 143302)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+# Contributor: Tim Hütz <tim at huetz.biz>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Sebastien Binet <binet at cern.ch>
+
+pkgbase=python-mpi4py
+pkgname=(python-mpi4py python2-mpi4py)
+pkgver=1.3.1
+pkgrel=3
+pkgdesc='Python bindings for the Message Passing Interface (MPI) standard'
+arch=(x86_64 i686)
+url='https://planet.scipy.org/'
+license=(BSD)
+makedepends=(python-setuptools python2-setuptools openmpi)
+source=(https://pypi.python.org/packages/source/m/mpi4py/mpi4py-$pkgver.tar.gz)
+sha1sums=('083a4a9b6793dfdbd852082d8b95da08bcf57290')
+
+prepare() {
+ cp -a mpi4py-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir/mpi4py-$pkgver"
+ python setup.py build
+
+ cd "$srcdir/mpi4py-$pkgver-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/mpi4py-$pkgver-py2"
+ python2 setup.py test
+
+ cd "$srcdir/mpi4py-$pkgver"
+ # Tests fail on Python3
+ # https://bitbucket.org/mpi4py/mpi4py/issues/2/fails-test-with-py33
+ # python setup.py test
+}
+
+package_python-mpi4py() {
+ depends=(python openmpi)
+
+ cd "$srcdir/mpi4py-$pkgver"
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-mpi4py() {
+ depends=(python2 openmpi)
+
+ cd "$srcdir/mpi4py-$pkgver-py2"
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
Property changes on: python-mpi4py/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list