[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Thu Oct 29 09:33:26 UTC 2015
Date: Thursday, October 29, 2015 @ 10:33:26
Author: fyan
Revision: 145236
addpkg: python-expects 0.7.2-1
Added:
python-expects/
python-expects/repos/
python-expects/trunk/
python-expects/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: python-expects/trunk/PKGBUILD
===================================================================
--- python-expects/trunk/PKGBUILD (rev 0)
+++ python-expects/trunk/PKGBUILD 2015-10-29 09:33:26 UTC (rev 145236)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-expects
+pkgname=('python-expects' 'python2-expects')
+pkgver=0.7.2
+pkgrel=1
+pkgdesc="Expressive and extensible TDD/BDD assertion library for Python"
+arch=('any')
+license=('Apache')
+url="https://github.com/jaimegildesagredo/expects"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/jaimegildesagredo/expects.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a expects{,-py2}
+}
+
+build() {
+ cd "$srcdir/expects"
+ python setup.py build
+
+ cd "$srcdir/expects-py2"
+ python2 setup.py build
+}
+
+package_python-expects() {
+ depends=('python')
+
+ cd expects
+ python setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-expects() {
+ depends=('python2')
+
+ cd expects-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
Property changes on: python-expects/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list