[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, October 29, 2015 @ 10:44:44
  Author: fyan
Revision: 145242

addpkg: python-dockerpty 0.3.4-1

Added:
  python-dockerpty/
  python-dockerpty/repos/
  python-dockerpty/trunk/
  python-dockerpty/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-dockerpty/trunk/PKGBUILD
===================================================================
--- python-dockerpty/trunk/PKGBUILD	                        (rev 0)
+++ python-dockerpty/trunk/PKGBUILD	2015-10-29 09:44:44 UTC (rev 145242)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Hideaki Takahashi <mymelo+aur at gmail.com>
+# Maintainer: Vincent Demeester <vincent at sbr.pm>
+
+pkgname=(python-dockerpty python2-dockerpty)
+pkgver=0.3.4
+pkgrel=1
+pkgdesc="Python library to use the pseudo-tty of a docker container"
+arch=('any')
+license=('Apache')
+url="https://github.com/d11wtq/dockerpty"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-docker-py' 'python2-docker-py'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-expects' 'python2-expects')
+source=("git+https://github.com/d11wtq/dockerpty.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a dockerpty{,-py2}
+}
+
+build() {
+  cd "$srcdir/dockerpty"
+  python setup.py build
+
+  cd "$srcdir/dockerpty-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/dockerpty"
+  py.test
+
+  cd "$srcdir/dockerpty-py2"
+  py.test2
+}
+
+package_python-dockerpty() {
+  depends=('python-six' 'python-docker-py')
+
+  cd dockerpty
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-dockerpty() {
+  depends=('python2-six' 'python2-docker-py')
+
+  cd dockerpty-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}


Property changes on: python-dockerpty/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property