[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, September 9, 2015 @ 10:46:52
  Author: fyan
Revision: 139661

addpkg: python-pytest-capturelog 0.7-1

Added:
  python-pytest-captruelog/
  python-pytest-captruelog/repos/
  python-pytest-captruelog/trunk/
  python-pytest-captruelog/trunk/PKGBUILD

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Added: python-pytest-captruelog/trunk/PKGBUILD
===================================================================
--- python-pytest-captruelog/trunk/PKGBUILD	                        (rev 0)
+++ python-pytest-captruelog/trunk/PKGBUILD	2015-09-09 08:46:52 UTC (rev 139661)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pytest-capturelog
+pkgname=('python-pytest-capturelog' 'python2-pytest-capturelog')
+_pypiname=pytest-capturelog
+pkgver=0.7
+_tag=RELEASE_0_7
+pkgrel=1
+pkgdesc='py.test plugin to capture log messages'
+arch=('any')
+license=('MIT')
+url='https://bitbucket.org/memedough/pytest-capturelog/overview'
+makedepends=('python-pytest' 'python2-pytest' 'python-setuptools' 'python2-setuptools' 'mercurial')
+source=("hg+https://felixonmars@bitbucket.org/memedough/pytest-capturelog#tag=$_tag")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a "${srcdir}/${_pypiname}"{,-py2}
+}
+
+build() {
+  cd "$srcdir/$_pypiname"
+  python setup.py build
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir/$_pypiname"
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.4/site-packages:$PYTHONPATH" py.test || warning "Tests failed"
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2 || warning "Tests failed"
+}
+
+package_python-pytest-capturelog() {
+  depends=('python-pytest')
+
+  cd "$srcdir/$_pypiname"
+  python setup.py install --root="$pkgdir"/ --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-pytest-capturelog() {
+  depends=('python2-pytest')
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py install --root="$pkgdir"/ --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+# vim:set ts=2 sw=2 et: