[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, September 9, 2015 @ 11:00:41
  Author: fyan
Revision: 139665

addpkg: python-apipkg 1.4-1

Added:
  python-apipkg/
  python-apipkg/repos/
  python-apipkg/trunk/
  python-apipkg/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: python-apipkg/trunk/PKGBUILD
===================================================================
--- python-apipkg/trunk/PKGBUILD	                        (rev 0)
+++ python-apipkg/trunk/PKGBUILD	2015-09-09 09:00:41 UTC (rev 139665)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-apipkg
+pkgname=('python-apipkg' 'python2-apipkg')
+pkgver=1.4
+pkgrel=1
+pkgdesc="Namespace control and lazy-import mechanism"
+arch=('any')
+license=('MIT')
+url=" http://bitbucket.org/hpk42/apipkg"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("http://pypi.python.org/packages/source/a/apipkg/apipkg-$pkgver.tar.gz")
+sha512sums=('118f806706944513f50d3cdef596b32f8ce585cfaf94d2531a6d260f90a0e2147177161aaa6f5d6823150e6182d0f73be3dc01259b8a2f8d710733a22ea54789')
+
+prepare() {
+  cp -a apipkg-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir/apipkg-${pkgver}"
+  python setup.py build
+
+  cd "$srcdir/apipkg-${pkgver}-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/apipkg-${pkgver}"
+  py.test
+
+  cd "$srcdir/apipkg-${pkgver}-py2"
+  py.test2
+}
+
+package_python-apipkg() {
+  depends=('python')
+
+  cd apipkg-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-apipkg() {
+  depends=('python2')
+
+  cd apipkg-${pkgver}-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+


Property changes on: python-apipkg/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property