[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, September 9, 2015 @ 12:00:55
  Author: fyan
Revision: 139675

addpkg: python-pytest-cov 2.1.0-1

Added:
  python-pytest-cov/
  python-pytest-cov/repos/
  python-pytest-cov/trunk/
  python-pytest-cov/trunk/PKGBUILD

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Added: python-pytest-cov/trunk/PKGBUILD
===================================================================
--- python-pytest-cov/trunk/PKGBUILD	                        (rev 0)
+++ python-pytest-cov/trunk/PKGBUILD	2015-09-09 10:00:55 UTC (rev 139675)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastien LEDUC <sebastien at sleduc.fr>
+# Contributor: Andrey Mikhaylenko <neithere at gmail dot com>
+
+pkgbase=python-pytest-cov
+pkgname=('python-pytest-cov' 'python2-pytest-cov')
+_pypiname=pytest-cov
+pkgver=2.1.0
+pkgrel=1
+pkgdesc='py.test plugin for coverage reporting with support for both centralised and distributed testing, including subprocesses and multiprocessing'
+arch=('any')
+license=('MIT')
+url='https://github.com/schlamar/pytest-cov'
+makedepends=('python-coverage' 'python2-coverage' 'python-setuptools' 'python2-setuptools'
+             'python-pytest' 'python2-pytest' 'git')
+checkdepends=('python-virtualenv' 'python2-virtualenv' 'python-process-tests' 'python2-process-tests'
+              'python-pytest-cache' 'python2-pytest-cache' 'python-pytest-xdist' 'python2-pytest-xdist'
+              'python-pytest-capturelog' 'python2-pytest-capturelog')
+source=("git+https://github.com/pytest-dev/pytest-cov.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a "${srcdir}/${_pypiname}"{,-py2}
+}
+
+build() {
+  cd "$srcdir/$_pypiname"
+  python setup.py build
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir/$_pypiname"
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.4/site-packages:$PYTHONPATH:$PWD/tests" py.test || warning "Tests failed"
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH:$PWD/tests" py.test2 || warning "Tests failed"
+}
+
+package_python-pytest-cov() {
+  depends=('python-pytest' 'python-coverage')
+
+  cd "$srcdir/$_pypiname"
+  python setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+package_python2-pytest-cov() {
+  depends=('python2-pytest' 'python2-coverage')
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py install --root="$pkgdir"/ --optimize=1
+}
+# vim:set ts=2 sw=2 et:


Property changes on: python-pytest-cov/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property