[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, September 9, 2015 @ 12:10:03
  Author: fyan
Revision: 139677

addpkg: python-wheel 0.24.0-1

Added:
  python-wheel/
  python-wheel/repos/
  python-wheel/trunk/
  python-wheel/trunk/PKGBUILD

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Added: python-wheel/trunk/PKGBUILD
===================================================================
--- python-wheel/trunk/PKGBUILD	                        (rev 0)
+++ python-wheel/trunk/PKGBUILD	2015-09-09 10:10:03 UTC (rev 139677)
@@ -0,0 +1,63 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Lance Chen <cyen0312 at gmail.com>
+
+_pypiname=wheel
+pkgbase=python-wheel
+pkgname=('python-wheel' 'python2-wheel')
+pkgver=0.24.0
+pkgrel=1
+pkgdesc="A built-package format for Python"
+arch=(any)
+url="https://pypi.python.org/pypi/wheel"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-jsonschema' 'python2-jsonschema' 'python-pytest-cov' 'python2-pytest-cov'
+              'python-keyring' 'python2-keyring')
+source=("https://pypi.python.org/packages/source/w/wheel/$_pypiname-$pkgver.tar.gz")
+md5sums=('3b0d66f0d127ea8befaa5d11453107fd')
+
+prepare() {
+  cp -a wheel-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/wheel-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/wheel-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir/wheel-$pkgver"
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.4/site-packages:$PYTHONPATH" py.test wheel
+
+  cd "$srcdir/wheel-$pkgver-py2"
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2 wheel
+}
+
+package_python-wheel() {
+  depends=('python')
+  optdepends=('python-keyring: for wheel.signatures')
+
+  cd "$srcdir/$_pypiname-$pkgver"
+  python setup.py install --root="$pkgdir/" --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-wheel() {
+  depends=('python2')
+  optdepends=('python2-keyring: for wheel.signatures')
+
+  cd "$srcdir/$_pypiname-$pkgver"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+  mv "$pkgdir/usr/bin/wheel" "$pkgdir/usr/bin/wheel2"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-wheel/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property