[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, December 14, 2016 @ 07:06:51
  Author: felixonmars
Revision: 199296

addpkg: python-snakefood 1.4.0.20160605-1

Added:
  python-snakefood/
  python-snakefood/repos/
  python-snakefood/trunk/
  python-snakefood/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: python-snakefood/trunk/PKGBUILD
===================================================================
--- python-snakefood/trunk/PKGBUILD	                        (rev 0)
+++ python-snakefood/trunk/PKGBUILD	2016-12-14 07:06:51 UTC (rev 199296)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+# Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
+
+pkgbase=python-snakefood
+pkgname=python2-snakefood
+pkgver=1.4.0.20160605
+_revision=6d55510bd30bf731ef9b4de5242733d12a478295
+pkgrel=1
+pkgdesc='Dependency Graphing for Python'
+arch=('any')
+url="http://furius.ca/snakefood"
+license=('GPL')
+depends=('python2-six')
+makedepends=('mercurial')
+checkdepends=('python2-pytest')
+source=("hg+https://bitbucket.org/blais/snakefood#revision=$_revision")
+sha256sums=('SKIP')
+
+prepare() {
+  sed -i 's|/usr/bin/env python|/usr/bin/env python2|' snakefood/bin/*
+}
+
+build() {
+  cd snakefood
+  python2 setup.py build
+}
+
+check() {
+  cd snakefood
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test2 || warning "Tests are broken"
+}
+
+package_python2-snakefood() {
+  cd snakefood
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-snakefood/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property