[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Wed Dec 14 07:14:46 UTC 2016
Date: Wednesday, December 14, 2016 @ 07:14:45
Author: felixonmars
Revision: 199300
addpkg: python-pytddmon 1.0.8-1
Added:
python-pytddmon/
python-pytddmon/repos/
python-pytddmon/trunk/
python-pytddmon/trunk/PKGBUILD
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Added: python-pytddmon/trunk/PKGBUILD
===================================================================
--- python-pytddmon/trunk/PKGBUILD (rev 0)
+++ python-pytddmon/trunk/PKGBUILD 2016-12-14 07:14:45 UTC (rev 199300)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: Thomas S Hatch <thatch45 at gmail.com>
+
+pkgbase=python-pytddmon
+pkgname=('python-pytddmon' 'python2-pytddmon')
+pkgver=1.0.8
+_commit=4b2875cfda88050537af58a4103ea8809c27ee1c
+pkgrel=1
+pkgdesc='Continuous unit testing in Python'
+arch=('any')
+url='http://pytddmon.org'
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/objarni/pytddmon.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a pytddmon{,-py2}
+}
+
+build() {
+ cd "$srcdir"/pytddmon
+ python setup.py build
+
+ cd "$srcdir"/pytddmon-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/pytddmon
+ python setup.py nosetests
+
+ cd "$srcdir"/pytddmon-py2
+ python2 setup.py nosetests
+}
+
+package_python-pytddmon() {
+ depends=('python')
+
+ cd pytddmon
+ python setup.py install --root="$pkgdir" -O1
+}
+
+package_python2-pytddmon() {
+ depends=('python2')
+
+ cd pytddmon-py2
+ python2 setup.py install --root="$pkgdir" -O1
+
+ mv "$pkgdir"/usr/bin/pytddmon{,2}.py
+}
Property changes on: python-pytddmon/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list