[arch-commits] Commit in python-requests-kerberos/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 02:50:49
  Author: bpiotrowski
Revision: 201806

archrelease: copy trunk to community-staging-any

Added:
  python-requests-kerberos/repos/community-staging-any/
  python-requests-kerberos/repos/community-staging-any/PKGBUILD
    (from rev 201805, python-requests-kerberos/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-requests-kerberos/repos/community-staging-any/PKGBUILD (from rev 201805, python-requests-kerberos/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 02:50:49 UTC (rev 201806)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-requests-kerberos
+pkgname=('python-requests-kerberos' 'python2-requests-kerberos')
+pkgver=0.11.0
+pkgrel=2
+pkgdesc="A kerberos of useful classes and functions to be used with python-requests."
+arch=('any')
+url="https://github.com/requests/requests-kerberos"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests'
+             'python-pykerberos' 'python2-pykerberos' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock')
+source=("git+https://github.com/requests/requests-kerberos.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a requests-kerberos{,-py2}
+}
+
+build() {
+  cd "$srcdir"/requests-kerberos
+  python setup.py build
+
+  cd "$srcdir"/requests-kerberos-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/requests-kerberos
+  py.test
+
+  cd "$srcdir"/requests-kerberos-py2
+  py.test2
+}
+
+package_python-requests-kerberos() {
+  depends=('python-requests' 'python-pykerberos')
+
+  cd "$srcdir"/requests-kerberos
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-requests-kerberos() {
+  depends=('python2-requests' 'python2-pykerberos')
+
+  cd "$srcdir"/requests-kerberos-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}