[arch-commits] Commit in python-requests-mock/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 02:51:26
  Author: bpiotrowski
Revision: 201808

archrelease: copy trunk to community-staging-any

Added:
  python-requests-mock/repos/community-staging-any/
  python-requests-mock/repos/community-staging-any/PKGBUILD
    (from rev 201807, python-requests-mock/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-requests-mock/repos/community-staging-any/PKGBUILD (from rev 201807, python-requests-mock/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 02:51:26 UTC (rev 201808)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-requests-mock
+pkgname=('python-requests-mock' 'python2-requests-mock')
+pkgver=1.2.0
+pkgrel=2
+pkgdesc="A mock of useful classes and functions to be used with python-requests."
+arch=('any')
+url="https://github.com/openstack/requests-mock"
+license=('Apache')
+makedepends=('python-pbr' 'python2-pbr' 'python-requests' 'python2-requests'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-testrepository' 'python2-testrepository' 'python-mock' 'python2-mock')
+source=("git+https://github.com/openstack/requests-mock.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a requests-mock{,-py2}
+}
+
+build() {
+  cd "$srcdir"/requests-mock
+  python setup.py build
+
+  cd "$srcdir"/requests-mock-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/requests-mock
+  python setup.py testr
+
+  cd "$srcdir"/requests-mock-py2
+  PYTHON=python2 python2 setup.py testr
+}
+
+package_python-requests-mock() {
+  depends=('python-requests' 'python-six')
+
+  cd requests-mock
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-requests-mock() {
+  depends=('python2-requests' 'python2-six')
+
+  cd requests-mock-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}