[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 12, 2016 @ 06:40:30
  Author: fyan
Revision: 161375

addpkg: lib32-imlib2 1.4.7-1

Added:
  lib32-imlib2/
  lib32-imlib2/repos/
  lib32-imlib2/trunk/
  lib32-imlib2/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: lib32-imlib2/trunk/PKGBUILD
===================================================================
--- lib32-imlib2/trunk/PKGBUILD	                        (rev 0)
+++ lib32-imlib2/trunk/PKGBUILD	2016-02-12 05:40:30 UTC (rev 161375)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Arjan Timmerman <arjan.archlinux.org>
+# Contributor: Tom Newsom <Jeepster.gmx.co.uk>
+# Contributor: GordonGR <gordongr at freemail.gr>
+
+pkgname=lib32-imlib2
+_pkgname=imlib2
+pkgver=1.4.7
+pkgrel=1
+pkgdesc="Library that does image file loading and saving as well as rendering, manipulation, arbitrary polygon support, lib32"
+url="http://sourceforge.net/projects/enlightenment/"
+arch=('x86_64')
+license=('BSD')
+depends=('lib32-libtiff' 'lib32-giflib' 'lib32-bzip2' 'lib32-freetype2' 'lib32-libxext' 'lib32-libpng' 'lib32-libid3tag' 'lib32-libjpeg-turbo' "${_pkgname}")
+source=("http://downloads.sourceforge.net/enlightenment/${_pkgname}-$pkgver.tar.bz2")
+md5sums=('f2f1418c376da6125453f90f2d58d938')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+  sed -i 's/@my_libs@//' imlib2-config.in
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  # Configure and Build
+  ./configure --prefix=/usr --sysconfdir=/etc/imlib2 --x-libraries=/usr/lib32 --enable-mmx --disable-amd64 --libdir=/usr/lib32 --libexecdir=/usr/lib32 
+
+  make
+}
+
+package() {
+  cd "${_pkgname}-$pkgver"
+  make DESTDIR="$pkgdir" install
+  cd "$pkgdir/usr"
+  rm -rf {bin,include,share/imlib2}/
+
+  install -Dm644 "$srcdir/${_pkgname}-$pkgver/COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}


Property changes on: lib32-imlib2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property