[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 12, 2016 @ 06:43:49
  Author: fyan
Revision: 161379

addpkg: lib32-libcaca 0.99.beta18-3

Added:
  lib32-libcaca/
  lib32-libcaca/repos/
  lib32-libcaca/trunk/
  lib32-libcaca/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: lib32-libcaca/trunk/PKGBUILD
===================================================================
--- lib32-libcaca/trunk/PKGBUILD	                        (rev 0)
+++ lib32-libcaca/trunk/PKGBUILD	2016-02-12 05:43:49 UTC (rev 161379)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Limao Luo <luolimao+AUR at gmail.com>
+# Contributor: GordonGR <gordongr at freemail.gr>
+
+_pkgname=libcaca
+pkgname=lib32-$_pkgname
+pkgver=0.99.beta18
+pkgrel=3
+pkgdesc="Color AsCii Art library (32-bit)"
+arch=("x86_64")
+url="http://caca.zoy.org/wiki/libcaca"
+license=('custom:WTFPL')
+depends=("$_pkgname" "lib32-imlib2")
+source=("http://libcaca.zoy.org/files/$_pkgname/$_pkgname-$pkgver.tar.gz")
+md5sums=('93d35dbdb0527d4c94df3e9a02e865cc')
+
+build() {
+    export CC="gcc -m32"
+    export CXX="g++ -m32"
+    export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+    cd $_pkgname-$pkgver/
+
+    ./configure \
+        --prefix=/usr \
+        --enable-shared \
+        --disable-doc \
+        --disable-cxx \
+        --disable-gl \
+        --disable-csharp \
+        --disable-python \
+        --disable-slang \
+        --libdir=/usr/lib32/ \
+        --libexecdir=/usr/lib32 \
+        --host=i686-unknown-linux-gnu
+    make
+}
+
+package() {
+    make -C $_pkgname-$pkgver DESTDIR="$pkgdir" install
+    rm -rf "$pkgdir"/usr/{bin,include,lib,share}/
+
+    rmdir "$pkgdir/usr/lib32/jni"
+}


Property changes on: lib32-libcaca/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property