[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Fri Feb 26 06:32:22 UTC 2016


    Date: Friday, February 26, 2016 @ 07:32:22
  Author: fyan
Revision: 163467

addpkg: python-oslo-i18n 3.4.0-1

Added:
  python-oslo-i18n/
  python-oslo-i18n/repos/
  python-oslo-i18n/trunk/
  python-oslo-i18n/trunk/PKGBUILD

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Added: python-oslo-i18n/trunk/PKGBUILD
===================================================================
--- python-oslo-i18n/trunk/PKGBUILD	                        (rev 0)
+++ python-oslo-i18n/trunk/PKGBUILD	2016-02-26 06:32:22 UTC (rev 163467)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-oslo-i18n
+pkgname=(python-oslo-i18n python2-oslo-i18n)
+pkgver=3.4.0
+pkgrel=1
+pkgdesc="Oslo i18n library"
+arch=('any')
+url="https://pypi.python.org/pypi/oslo.i18n/$pkgver"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+             'python-babel' 'python2-babel')
+checkdepends=('python-mock' 'python2-mock' 'python-oslotest' 'python2-oslotest'
+              'python-oslo-config' 'python2-oslo-config')
+options=('!emptydirs')
+source=("git+https://git.openstack.org/openstack/oslo.i18n#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a oslo.i18n{,-py2}
+}
+
+build() {
+  cd "$srcdir"/oslo.i18n
+  python setup.py build
+
+  cd "$srcdir"/oslo.i18n-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/oslo.i18n
+  python setup.py testr
+
+  cd "$srcdir"/oslo.i18n-py2
+  python2 setup.py testr
+}
+
+package_python-oslo-i18n() {
+  depends=('python-six' 'python-pbr' 'python-babel')
+
+  cd "$srcdir"/oslo.i18n
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-oslo-i18n() {
+  depends=('python2-six' 'python2-pbr' 'python2-babel')
+
+  cd "$srcdir"/oslo.i18n-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-oslo-i18n/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list