[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 26, 2016 @ 07:56:21
  Author: fyan
Revision: 163474

addpkg: python-oslo-utils 3.7.0-1

Added:
  python-oslo-utils/
  python-oslo-utils/repos/
  python-oslo-utils/trunk/
  python-oslo-utils/trunk/PKGBUILD

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Added: python-oslo-utils/trunk/PKGBUILD
===================================================================
--- python-oslo-utils/trunk/PKGBUILD	                        (rev 0)
+++ python-oslo-utils/trunk/PKGBUILD	2016-02-26 06:56:21 UTC (rev 163474)
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-oslo-utils
+pkgname=(python-oslo-utils python2-oslo-utils)
+pkgver=3.7.0
+pkgrel=1
+pkgdesc="Oslo Utility library"
+arch=('any')
+url="https://pypi.python.org/pypi/oslo.utils/$pkgver"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr' 'python2-funcsigs'
+             'python-iso8601' 'python2-iso8601' 'python-oslo-i18n' 'python2-oslo-i18n' 'python2-monotonic'
+             'python-pytz' 'python2-pytz' 'python-netaddr' 'python2-netaddr' 'python-netifaces'
+             'python2-netifaces' 'python-debtcollector' 'python2-debtcollector')
+checkdepends=('python-oslotest' 'python2-oslotest')
+source=("git+https://git.openstack.org/openstack/oslo.utils#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a oslo.utils{,-py2}
+
+  # Use python 3's standard monotonic function
+  sed -i '/monotonic/d' oslo.utils/requirements.txt
+  sed -i 's/from monotonic import monotonic/from time import monotonic/' oslo.utils/oslo_utils/timeutils.py
+}
+
+build() {
+  cd "$srcdir"/oslo.utils
+  python setup.py build
+
+  cd "$srcdir"/oslo.utils-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/oslo.utils
+  python setup.py testr
+
+  cd "$srcdir"/oslo.utils-py2
+  PYTHON=python2 python2 setup.py testr
+}
+
+package_python-oslo-utils() {
+  depends=('python-six' 'python-pbr' 'python-iso8601' 'python-oslo-i18n' 'python-pytz'
+           'python-netaddr' 'python-netifaces' 'python-debtcollector')
+
+  cd "$srcdir"/oslo.utils
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-oslo-utils() {
+  depends=('python2-six' 'python2-pbr' 'python2-iso8601' 'python2-oslo-i18n' 'python2-monotonic'
+           'python2-pytz' 'python2-netaddr' 'python2-netifaces' 'python2-debtcollector'
+           'python2-funcsigs')
+
+  cd "$srcdir"/oslo.utils-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-oslo-utils/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property