[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Tuesday, January 5, 2016 @ 18:29:05
  Author: anthraxx
Revision: 155529

addpkg: enjarify 1.0.0-2

Added:
  enjarify/
  enjarify/repos/
  enjarify/trunk/
  enjarify/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: enjarify/trunk/PKGBUILD
===================================================================
--- enjarify/trunk/PKGBUILD	                        (rev 0)
+++ enjarify/trunk/PKGBUILD	2016-01-05 17:29:05 UTC (rev 155529)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Lance Chen <cyen0312 at gmail.com>
+
+pkgname=enjarify
+pkgver=1.0.0
+pkgrel=2
+pkgdesc="Translates Dalvik bytecode to equivalent Java bytecode"
+url="https://github.com/google/enjarify"
+arch=('any')
+license=('Apache')
+depends=("python")
+makedepends=('git')
+checkdepends=('java-runtime')
+source=(${pkgname}::"git+https://github.com/google/enjarify#tag=${pkgver}")
+sha512sums=('SKIP')
+
+prepare() {
+  cd ${pkgname}
+  sed -r 's| -Xss515m||g' -i enjarify/runtests.py
+}
+
+build() {
+  cd ${pkgname}
+  python -m compileall .
+  python -O -m compileall .
+}
+
+check() {
+  cd ${pkgname}
+  LC_CTYPE=en_US.UTF-8 python -m enjarify.runtests
+}
+
+package() {
+  cd ${pkgname}
+  install -d "${pkgdir}/usr/lib/enjarify"
+  cp -R enjarify enjarify.sh "${pkgdir}/usr/lib/enjarify"
+  install -d "${pkgdir}/usr/bin"
+  ln -s /usr/lib/enjarify/enjarify.sh "${pkgdir}/usr/bin/enjarify"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: