[arch-commits] Commit in (4 files)
Anatol Pomozov
anatolik at archlinux.org
Tue Jan 5 18:00:07 UTC 2016
Date: Tuesday, January 5, 2016 @ 19:00:07
Author: anatolik
Revision: 155535
Add python-tarantool module
Added:
python-tarantool/
python-tarantool/repos/
python-tarantool/trunk/
python-tarantool/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: python-tarantool/trunk/PKGBUILD
===================================================================
--- python-tarantool/trunk/PKGBUILD (rev 0)
+++ python-tarantool/trunk/PKGBUILD 2016-01-05 18:00:07 UTC (rev 155535)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+
+pkgbase=python-tarantool
+pkgname=(python-tarantool python2-tarantool)
+pkgver=0.5.1
+pkgrel=1
+pkgdesc='Python client library for Tarantool 1.6 Database'
+arch=(any)
+url='https://github.com/tarantool/tarantool-python'
+license=(BSD)
+makedepends=(python-setuptools python2-setuptools python-msgpack python2-msgpack python-yaml python2-yaml python-six python2-six)
+source=(https://pypi.python.org/packages/source/t/tarantool/tarantool-$pkgver.tar.gz)
+sha1sums=('9a8e4a23ca8bd2ad101d1e641752a4851655c725')
+
+prepare() {
+ cp -a tarantool-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir/tarantool-$pkgver"
+ python setup.py build
+
+ cd "$srcdir/tarantool-$pkgver-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/tarantool-$pkgver"
+ # currently tests fail for python3
+ #python setup.py test
+
+ cd "$srcdir/tarantool-$pkgver-py2"
+ python2 setup.py test
+}
+
+package_python-tarantool() {
+ depends=(python python-msgpack python-yaml python-six)
+
+ cd "$srcdir/tarantool-$pkgver"
+ python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-tarantool() {
+ depends=(python2 python2-msgpack python2-yaml python2-six)
+
+ cd "$srcdir/tarantool-$pkgver-py2"
+ python2 setup.py install --root="$pkgdir" --optimize=1
+}
Property changes on: python-tarantool/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list