[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Tue Jun 28 16:07:14 UTC 2016
Date: Tuesday, June 28, 2016 @ 16:07:14
Author: felixonmars
Revision: 181505
addpkg: python-rfc3986 0.3.1-1
Added:
python-rfc3986/
python-rfc3986/repos/
python-rfc3986/trunk/
python-rfc3986/trunk/PKGBUILD
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Added: python-rfc3986/trunk/PKGBUILD
===================================================================
--- python-rfc3986/trunk/PKGBUILD (rev 0)
+++ python-rfc3986/trunk/PKGBUILD 2016-06-28 16:07:14 UTC (rev 181505)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgbase=python-rfc3986
+pkgname=(python-rfc3986 python2-rfc3986)
+pkgver=0.3.1
+pkgrel=1
+pkgdesc="Validating URI References per RFC 3986"
+arch=('any')
+license=('Apache')
+url="https://rfc3986.readthedocs.org/"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("https://pypi.io/packages/source/r/rfc3986/rfc3986-$pkgver.tar.gz")
+md5sums=('4a0cc842d0e1b061f1b5202917095340')
+
+prepare() {
+ cp -a rfc3986-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/rfc3986-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/rfc3986-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/rfc3986-$pkgver
+ python setup.py ptr
+
+ cd "$srcdir"/rfc3986-$pkgver-py2
+ python2 setup.py ptr
+}
+
+package_python-rfc3986() {
+ depends=('python')
+
+ cd rfc3986-$pkgver
+ python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-rfc3986() {
+ depends=('python2')
+
+ cd rfc3986-$pkgver-py2
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+}
Property changes on: python-rfc3986/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list