[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, June 28, 2016 @ 16:46:04
  Author: felixonmars
Revision: 181515

addpkg: python-fastpbkdf2 0.1-1

Added:
  python-fastpbkdf2/
  python-fastpbkdf2/repos/
  python-fastpbkdf2/trunk/
  python-fastpbkdf2/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-fastpbkdf2/trunk/PKGBUILD
===================================================================
--- python-fastpbkdf2/trunk/PKGBUILD	                        (rev 0)
+++ python-fastpbkdf2/trunk/PKGBUILD	2016-06-28 16:46:04 UTC (rev 181515)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgbase=python-fastpbkdf2
+pkgname=(python-fastpbkdf2 python2-fastpbkdf2)
+pkgver=0.1
+pkgrel=1
+pkgdesc="A faster implementation of PBKDF2"
+arch=('i686' 'x86_64')
+license=('Apache')
+url="https://github.com/Ayrx/python-fastpbkdf2"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-cffi' 'python2-cffi' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner') 
+source=("git+https://github.com/Ayrx/python-fastpbkdf2.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a python-fastpbkdf2{,-py2}
+}
+
+build() {
+  cd "$srcdir"/python-fastpbkdf2
+  python setup.py build
+
+  cd "$srcdir"/python-fastpbkdf2-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/python-fastpbkdf2
+  python setup.py ptr
+
+  cd "$srcdir"/python-fastpbkdf2-py2
+  python2 setup.py ptr
+}
+
+package_python-fastpbkdf2() {
+  depends=('python-cffi' 'python-six')
+
+  cd python-fastpbkdf2
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-fastpbkdf2() {
+  depends=('python2-cffi' 'python2-six')
+
+  cd python-fastpbkdf2-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}


Property changes on: python-fastpbkdf2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property