[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Fri May 27 03:20:15 UTC 2016


    Date: Friday, May 27, 2016 @ 05:20:14
  Author: fyan
Revision: 177153

addpkg: python-case 1.1.4-1

Added:
  python-case/
  python-case/repos/
  python-case/trunk/
  python-case/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-case/trunk/PKGBUILD
===================================================================
--- python-case/trunk/PKGBUILD	                        (rev 0)
+++ python-case/trunk/PKGBUILD	2016-05-27 03:20:14 UTC (rev 177153)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-case
+pkgname=('python-case' 'python2-case')
+pkgver=1.1.4
+pkgrel=1
+pkgdesc="Python unittest Utilities"
+arch=('any')
+license=('BSD')
+url="https://github.com/celery/case"
+makedepends=('python-nose' 'python2-nose' 'python2-mock' 'python2-unittest2' 'git')
+checkdepends=('python-coverage' 'python2-coverage')
+source=("git+https://github.com/celery/case.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a case{,-py2}
+}
+
+build() {
+  cd "$srcdir"/case
+  python setup.py build
+
+  cd "$srcdir"/case-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/case
+  nosetests3
+
+  cd "$srcdir"/case-py2
+  nosetests2
+}
+
+package_python-case() {
+  depends=('python-nose')
+
+  cd case
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-case() {
+  depends=('python2-nose' 'python2-mock' 'python2-unittest2')
+
+  cd case-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-case/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list