[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, May 27, 2016 @ 05:27:58
  Author: fyan
Revision: 177157

addpkg: python-vine 1.1.0-1

Added:
  python-vine/
  python-vine/repos/
  python-vine/trunk/
  python-vine/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-vine/trunk/PKGBUILD
===================================================================
--- python-vine/trunk/PKGBUILD	                        (rev 0)
+++ python-vine/trunk/PKGBUILD	2016-05-27 03:27:58 UTC (rev 177157)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-vine
+pkgname=('python-vine' 'python2-vine')
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Promises, promises, promises"
+arch=('any')
+license=('BSD')
+url="https://github.com/celery/vine"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-case' 'python2-case' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/celery/vine.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a vine{,-py2}
+}
+
+build() {
+  cd "$srcdir"/vine
+  python setup.py build
+
+  cd "$srcdir"/vine-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/vine
+  python setup.py test
+
+  cd "$srcdir"/vine-py2
+  python2 setup.py test
+}
+
+package_python-vine() {
+  depends=('python-case')
+
+  cd vine
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-vine() {
+  depends=('python2-case')
+
+  cd vine-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-vine/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property