[arch-commits] Commit in dolphin/repos (2 files)

[Antonio Rojas]

    Date: Friday, July 21, 2017 @ 19:37:54
  Author: arojas
Revision: 300958

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  dolphin/repos/kde-unstable-x86_64/
  dolphin/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 300957, dolphin/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: dolphin/repos/kde-unstable-x86_64/PKGBUILD (from rev 300957, dolphin/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2017-07-21 19:37:54 UTC (rev 300958)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux,org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgname=dolphin
+pkgver=17.07.80
+pkgrel=1
+pkgdesc="File Manager"
+arch=(i686 x86_64)
+url="https://kde.org/applications/system/dolphin/"
+license=(LGPL)
+depends=(baloo-widgets knewstuff kio-extras kuiserver kcmutils)
+makedepends=(extra-cmake-modules kdoctools python)
+optdepends=('kde-cli-tools: for editing file type options' 'ffmpegthumbs: video thumbnails' 
+            'ruby: installing new service menus from KDE Store' 'kdegraphics-thumbnailers: PDF and PS thumbnails' 'konsole: terminal panel')
+conflicts=('kdebase-dolphin<15.08')
+replaces=(kdebase-dolphin)
+groups=(kde-applications kdebase)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('b4dfc52969477687bf829bffa86a391c9a23bef1e7fcd0b0ac5c6d029309bbde'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DKDE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}