[arch-commits] Commit in kate/repos (kde-unstable-x86_64 kde-unstable-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Fri Jul 21 19:38:08 UTC 2017
Date: Friday, July 21, 2017 @ 19:38:07
Author: arojas
Revision: 300959
archrelease: copy kde-unstable to kde-unstable-x86_64
Added:
kate/repos/kde-unstable-x86_64/
kate/repos/kde-unstable-x86_64/PKGBUILD
(from rev 300958, kate/kde-unstable/PKGBUILD)
----------+
PKGBUILD | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 62 insertions(+)
Copied: kate/repos/kde-unstable-x86_64/PKGBUILD (from rev 300958, kate/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD (rev 0)
+++ kde-unstable-x86_64/PKGBUILD 2017-07-21 19:38:07 UTC (rev 300959)
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=kate
+pkgname=(kwrite kate)
+pkgver=17.07.80
+pkgrel=1
+arch=(i686 x86_64)
+license=(GPL LGPL FDL)
+makedepends=(extra-cmake-modules kdoctools python plasma-framework knewstuff ktexteditor threadweaver kitemmodels kactivities)
+source=("https://download.kde.org/unstable/applications/${pkgver}/src/${pkgbase}-${pkgver}.tar.xz"{,.sig})
+sha256sums=('2f94c275eace2da34f74896c77e6cefa206cda840ccb02ef55d7ddfe526b2f97'
+ 'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid at kde.org>
+ F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+ cmake ../$pkgbase-$pkgver \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DKDE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package_kwrite() {
+ pkgdesc="Text Editor"
+ groups=(kde-applications kdebase)
+ url="https://www.kde.org/applications/utilities/kwrite/"
+ depends=(ktexteditor kactivities hicolor-icon-theme)
+
+ cd build
+ make DESTDIR="$pkgdir" install
+
+ find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
+ rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
+ "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
+ "$pkgdir"/usr/share/katexmltools \
+ "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{kterustcompletion,tabswitcherplugin}.mo \
+ "$pkgdir"/usr/share/plasma/plasmoids
+}
+
+package_kate() {
+ pkgdesc="Advanced Text Editor"
+ groups=(kde-applications kdebase)
+ url="https://www.kde.org/applications/utilities/kate/"
+ depends=(knewstuff ktexteditor threadweaver kitemmodels kactivities hicolor-icon-theme)
+ optdepends=('konsole: open a terminal in Kate')
+
+ cd build
+ make DESTDIR="$pkgdir" install
+
+ find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
+ rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
+}
More information about the arch-commits
mailing list