[arch-commits] Commit in (4 files)

[Jerome Leclanche]

    Date: Friday, June 23, 2017 @ 18:46:26
  Author: jleclanche
Revision: 240534

terraform: Moved from AUR

Added:
  terraform/
  terraform/repos/
  terraform/trunk/
  terraform/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: terraform/trunk/PKGBUILD
===================================================================
--- terraform/trunk/PKGBUILD	                        (rev 0)
+++ terraform/trunk/PKGBUILD	2017-06-23 18:46:26 UTC (rev 240534)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Jerome Leclanche <jerome at leclan.ch>
+
+pkgname=terraform
+pkgver=0.9.7
+pkgrel=1
+pkgdesc="Tool for building, changing, and versioning infrastructure safely and efficiently"
+url="http://www.terraform.io/"
+arch=("i686" "x86_64")
+license=("MPL")
+makedepends=("go" "godep" "git" "mercurial")
+conflicts=("terraform-bin")
+_gourl=github.com/hashicorp
+source=("https://github.com/hashicorp/terraform/archive/v$pkgver.tar.gz")
+sha256sums=("2af004ee5a155317e6df0158a5d9121d15aa349202ca7d7dd8321f2d9af2218c")
+
+
+prepare() {
+	mkdir -p "$srcdir/src/$_gourl"
+	rm -rf "${srcdir}/src/$_gourl/$pkgname"
+	mv -f "terraform-$pkgver" "$srcdir/src/$_gourl/$pkgname"
+	msg2 "Fetching dependencies"
+	cd "$srcdir/src/$_gourl/$pkgname"
+	GOPATH="$srcdir" go get -u github.com/mitchellh/gox
+	GOPATH="$srcdir" go get -u golang.org/x/tools/cmd/stringer
+}
+
+
+build() {
+	msg2 "Build program"
+	cd "$srcdir/src/$_gourl/$pkgname"
+	GOPATH="$srcdir" PATH="$srcdir/bin:$PATH" TF_DEV=1 TF_QUICKDEV=1 make bin
+}
+
+
+package() {
+	cd "$srcdir/bin"
+	install -Dm755 terraform "$pkgdir/usr/bin/terraform"
+
+	cd "$srcdir/src/$_gourl/$pkgname"
+	# Zsh completion
+	install -D contrib/zsh-completion/_terraform "$pkgdir/usr/share/zsh/site-functions/_terraform"
+}


Property changes on: terraform/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property